Nuking old lua files

[Ohidosee]

Ok, this isn't a question about coding, but I figured this may be a good place to ask.

Is there a way, via program or something, that would delete all of my old lua files that are not associated with addons any longer?

I've had the same UI since forever. It's game thru some changes, but, bliz taking some tips from the community and authors being bad ass, some functions have been combined or became obsolete.

I still have lua files in my saved variables from probably 2+ years ago that i obviously don't need. If i ever downloaded the addon again I'd just start over at this point.

Thanks for your time!

[Fizzlemizz]

Given the the saved variables files are written out each time you exit the game then any that are older than the last time you played belong to addons that are no longer in use. Sort by date last modified and delete (or move elswhere for later use) the older ones.

[SDPhantom]

If you're running Windows, I whipped up a batch file that scans your WTF folder and checks for orphaned SavedVariable files against your installed addons. It also removes all of the redundant backup files that WoW likes to create.

@echo off
pushd "C:\Program Files (x86)\World of Warcraft\WTF\Account"
 
del /s *.bak
del /s *.old
 
for /d %%i in (*) do (
    if exist %%i\SavedVariables\ (
        echo Account: %%i
 
        for %%j in ("%%i\SavedVariables\*.lua") do (
            echo GlobalSV: %%~nj
            if not exist ..\..\Interface\AddOns\%%~nj\ (
                echo Delete: %%~nj
                del "%%j"
            )
        )
 
        for /d %%j in ("%%i\*") do (
            for /d %%k in ("%%j\*") do (
                echo Character: %%k
                for %%l in ("%%k\SavedVariables\*.lua") do (
                    echo CharSV: %%~nl
                    if not exist ..\..\Interface\AddOns\%%~nl\ (
                        echo Delete: %%~nl
                        del "%%l"
                    )
                )
            )
        )
    )
)
 
popd
pause

Just copy/paste this into a text file, make sure the path in line 2 matches where your WoW account folder is located, and change the extension to .bat or .cmd, both do the same thing. If you want to leave the redundant backup files alone, remove lines 4 and 5. You can delete the echo lines if you want. I like my batch files to be verbose so I know it's doing its job.

[Ohidosee]

Originally Posted by Fizzlemizz Given the the saved variables files are written out each time you exit the game then any that are older than the last time you played belong to addons that are no longer in use. Sort by date last modified and delete (or move elswhere for later use) the older ones.

Didn't even think of that, thanks ! Sometimes the most obvious solutions have to smack me in the face for me to see it.

[Ohidosee]

Originally Posted by SDPhantom If you're running Windows, ....

Thanks SDPhantom, I'll give this a shot, too!